Package kerykeion and swiss ephemerisHEADlive

This took quite a bit of work to package, and it's not a perfect package, but I
think it will do to get Biz/Astrologer.py working.

8 files changed, 229 insertions, 1 deletions

diff --git a/Omni/Bild/Deps.nix b/Omni/Bild/Deps.nix
index ca296d4..806e7b1 100644
--- a/Omni/Bild/Deps.nix
+++ b/Omni/Bild/Deps.nix
@@ -34,6 +34,8 @@ in {
 
   radicale = dontCheck super.radicale;
 
+  sweph-data = super.callPackage ./Deps/sweph-data.nix {};
+
   thrift = dontCheck super.thrift;
 
   valkey = dontCheck super.valkey;
diff --git a/Omni/Bild/Deps/kerykeion.nix b/Omni/Bild/Deps/kerykeion.nix
new file mode 100644
index 0000000..d887231
--- /dev/null
+++ b/Omni/Bild/Deps/kerykeion.nix
@@ -0,0 +1,72 @@
+{
+  buildPythonPackage,
+  lib,
+  poetry-core,
+  pytestCheckHook,
+  pytz,
+  pyswisseph,
+  pydantic,
+  requests,
+  requests-cache,
+  scour,
+  simple-ascii-tables,
+  typing-extensions,
+  sources,
+  setuptools,
+}:
+buildPythonPackage rec {
+  pname = "kerykeion";
+  version = sources.kerykeion.version;
+  pyproject = true;
+
+  src = sources.kerykeion;
+
+  nativeBuildInputs = [poetry-core];
+
+  propagatedBuildInputs = [
+    pyswisseph
+    pydantic
+    scour
+    requests-cache
+    requests
+    simple-ascii-tables
+    pytz
+    typing-extensions
+    setuptools
+  ];
+
+  preBuild = ''
+    cat <<EOF >> pyproject.toml
+    [project]
+    name = "kerykeion"
+    version = "${sources.kerykeion.version}"
+
+    [tool.setuptools.packages.find]
+    where = ["."]
+    include = ["kerykeion*", "tests"]
+    namespaces = false
+
+    [build-system]
+    build-backend = "setuptools.build_meta"
+    requires = ["setuptools"]
+    EOF
+  '';
+
+  nativeCheckInputs = [pytestCheckHook];
+
+  pythonImportsCheck = ["kerykeion"];
+
+  # almost all tests perform network requests to api.geonames.org
+  enabledTests = [
+    "test_ephemeris_data"
+    "test_settings"
+  ];
+
+  meta = with lib; {
+    homepage = "https://www.kerykeion.net/";
+    description = "A python library for astrology";
+    changelog = "https://github.com/g-battaglia/kerykeion/releases/tag/v${version}";
+    license = licenses.agpl3Only;
+    maintainers = with maintainers; [bsima];
+  };
+}
diff --git a/Omni/Bild/Deps/pyswisseph.nix b/Omni/Bild/Deps/pyswisseph.nix
new file mode 100644
index 0000000..36c805e
--- /dev/null
+++ b/Omni/Bild/Deps/pyswisseph.nix
@@ -0,0 +1,41 @@
+{
+  buildPythonPackage,
+  lib,
+  setuptools,
+  wheel,
+  sources,
+  sweph-data,
+}:
+buildPythonPackage rec {
+  pname = "pyswisseph";
+  version = sources.pyswisseph.version;
+  format = "setuptools";
+
+  src = sources.pyswisseph;
+
+  nativeBuildInputs = [
+    setuptools
+    wheel
+  ];
+
+  # Disable system library detection to use bundled versions
+  preBuild = ''
+    substituteInPlace setup.py \
+      --replace-fail "swe_detection = True" "swe_detection = False" \
+      --replace-fail "sqlite3_detection = True" "sqlite3_detection = False"
+  '';
+
+  # Set ephemeris path to use sweph-data
+  postInstall = ''
+    export SE_EPHE_PATH=${sweph-data}/share/sweph/ephe
+  '';
+
+  pythonImportsCheck = ["swisseph"];
+
+  meta = with lib; {
+    homepage = "https://astrorigin.com/pyswisseph";
+    description = "Python extension to the Swiss Ephemeris";
+    license = licenses.agpl3Only;
+    maintainers = with maintainers; [bsima];
+  };
+}
diff --git a/Omni/Bild/Deps/simple-ascii-tables.nix b/Omni/Bild/Deps/simple-ascii-tables.nix
new file mode 100644
index 0000000..f2aa5d9
--- /dev/null
+++ b/Omni/Bild/Deps/simple-ascii-tables.nix
@@ -0,0 +1,28 @@
+{
+  buildPythonPackage,
+  lib,
+  poetry-core,
+  setuptools,
+  pytestCheckHook,
+  sources,
+}:
+buildPythonPackage rec {
+  pname = "simple-ascii-tables";
+  version = sources.simple-ascii-tables.version;
+  pyproject = true;
+
+  src = sources.simple-ascii-tables;
+
+  nativeBuildInputs = [poetry-core setuptools];
+
+  nativeCheckInputs = [pytestCheckHook];
+
+  pythonImportsCheck = ["simple_ascii_tables"];
+
+  meta = with lib; {
+    homepage = "https://pypi.org/project/simple-ascii-tables/";
+    description = "Simple, minimal, dependency-free ASCII tables for Python";
+    license = licenses.mit;
+    maintainers = with maintainers; [bsima];
+  };
+}
diff --git a/Omni/Bild/Deps/sweph-data.nix b/Omni/Bild/Deps/sweph-data.nix
new file mode 100644
index 0000000..02e373f
--- /dev/null
+++ b/Omni/Bild/Deps/sweph-data.nix
@@ -0,0 +1,38 @@
+{
+  stdenv,
+  fetchurl,
+  lib,
+}:
+stdenv.mkDerivation rec {
+  pname = "sweph-data";
+  version = "2023";
+
+  srcs = [
+    (fetchurl {
+      url = "https://github.com/aloistr/swisseph/raw/master/ephe/seas_18.se1";
+      sha256 = "0nvbd2kx99zsq3mlinabvjvhjm3rdq3middflq4prqsl2smc5naz";
+    })
+    (fetchurl {
+      url = "https://github.com/aloistr/swisseph/raw/master/ephe/semo_18.se1";
+      sha256 = "10191sx3nnbh827y7jpa4n3fj8d8563d4kp0qfdml2xwypdm9ypc";
+    })
+    (fetchurl {
+      url = "https://github.com/aloistr/swisseph/raw/master/ephe/sepl_18.se1";
+      sha256 = "18bfgg13sj9s6rv3zwbx1qx7k1bngyp1sw8xvnhfds8v7ip42zhb";
+    })
+  ];
+
+  unpackPhase = "true";
+
+  installPhase = ''
+    mkdir -p $out/share/sweph/ephe
+    for src in $srcs; do
+      cp $src $out/share/sweph/ephe/$(stripHash $src)
+    done
+  '';
+
+  meta = with lib; {
+    description = "Swiss Ephemeris data files";
+    license = licenses.agpl3Only;
+  };
+}
diff --git a/Omni/Bild/Python.nix b/Omni/Bild/Python.nix
index 5d1705a..f1056b1 100644
--- a/Omni/Bild/Python.nix
+++ b/Omni/Bild/Python.nix
@@ -10,6 +10,7 @@ _self: super: {
         anyio = dontCheck pysuper.anyio;
         interegular = callPackage ./Deps/interegular.nix {};
         ipython = dontCheck pysuper.ipython;
+        kerykeion = callPackage ./Deps/kerykeion.nix {};
         llm = super.overrideSrc pysuper.llm super.sources.llm;
         llm-ollama = pysuper.pkgs.python312.pkgs.callPackage ./Deps/llm-ollama.nix {
           ollama = pyself.ollama;
@@ -34,6 +35,8 @@ _self: super: {
         pydantic-ai-slim = callPackage ./Deps/pydantic-ai-slim.nix {};
         pydantic-graph = callPackage ./Deps/pydantic-graph.nix {};
         perscache = callPackage ./Deps/perscache.nix {};
+        pyswisseph = callPackage ./Deps/pyswisseph.nix {};
+        simple-ascii-tables = callPackage ./Deps/simple-ascii-tables.nix {};
         tokenizers = dontCheck pysuper.tokenizers;
       };
   };
diff --git a/Omni/Bild/Sources.json b/Omni/Bild/Sources.json
index 51655d3..f5a2d2b 100644
--- a/Omni/Bild/Sources.json
+++ b/Omni/Bild/Sources.json
@@ -73,6 +73,19 @@
         "url": "https://github.com/MegaIng/interegular/archive/v0.2.1.tar.gz",
         "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz"
     },
+    "kerykeion": {
+        "branch": "master",
+        "description": "Data-Driven Astrology  💫  Kerykeion is a Python library for astrology. It generates SVG charts and extracts detailed structured data for birth charts, synastry, transits, composite charts, and more.",
+        "homepage": "https://kerykeion.net",
+        "owner": "g-battaglia",
+        "repo": "kerykeion",
+        "rev": "V4.26.0",
+        "sha256": "0c2r2q0qgjzzjp7d3b1f0mqb508kj3b6767cw7kd2nn47wihb8g8",
+        "type": "tarball",
+        "url": "https://github.com/g-battaglia/kerykeion/archive/V4.26.0.tar.gz",
+        "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz",
+        "version": "4.26.0"
+    },
     "llm": {
         "branch": "main",
         "description": "Access large language models from the command-line",
@@ -242,6 +255,20 @@
         "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz",
         "version": "0.1.9"
     },
+    "pyswisseph": {
+        "branch": "master",
+        "description": "Python extension to the Swiss Ephemeris",
+        "homepage": "https://astrorigin.com/pyswisseph",
+        "repo": "https://github.com/astrorigin/pyswisseph",
+        "rev": "778903d59bed84b8da020cee77f1995b0df5106b",
+        "sha256": "1qbwnhw2rv6qh5nzgj47baxfmx29wim0bkrvfzfg6cy7g7xxfbz6",
+        "submodules": true,
+        "tag": "v2.10.03.2",
+        "type": "git",
+        "url": "https://github.com/astrorigin/pyswisseph/archive/v2.10.03.2.tar.gz",
+        "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz",
+        "version": "2.10.03.2"
+    },
     "radicale": {
         "branch": "master",
         "description": "A simple CalDAV (calendar) and CardDAV (contact) server.",
@@ -267,5 +294,18 @@
         "url": "https://github.com/feuerbach/regex-applicative/archive/449519c38e65753345e9a008362c011cb7a0a4d9.tar.gz",
         "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz",
         "version": "0.3.4"
+    },
+    "simple-ascii-tables": {
+        "branch": "master",
+        "description": "Simple, minimal, dependency-free ASCII tables for Python.",
+        "homepage": "https://pypi.org/project/simple-ascii-tables/",
+        "owner": "g-battaglia",
+        "repo": "simple-ascii-tables",
+        "rev": "V1.0.0",
+        "sha256": "0zzpis810kgwybaiyj2im3fcmjvadpb3gls4k2j13k0z909vind7",
+        "type": "tarball",
+        "url": "https://github.com/g-battaglia/simple-ascii-tables/archive/V1.0.0.tar.gz",
+        "url_template": "https://github.com/<owner>/<repo>/archive/<rev>.tar.gz",
+        "version": "1.0.0"
     }
 }
diff --git a/Omni/Bild/Sources.nix b/Omni/Bild/Sources.nix
index dbcd147..93bb9d8 100644
--- a/Omni/Bild/Sources.nix
+++ b/Omni/Bild/Sources.nix
@@ -44,11 +44,15 @@ let
       else
         abort
         "In git source '${name}': Please specify `ref`, `tag` or `branch`!";
+    submodules =
+      if spec ? submodules
+      then spec.submodules
+      else false;
   in
     builtins.fetchGit {
       url = spec.repo;
       inherit (spec) rev;
-      inherit ref;
+      inherit ref submodules;
     };
 
   fetch_local = spec: spec.path;