{-# LANGUAGE LambdaCase #-}
{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE NoImplicitPrelude #-}

-- | Log reporting interface
--
-- Some guidelines:
--
--    * don't allow `mark` in final code
--
--    * don't use `br` after `info`, unless verbose mode is requested (--loud flag in bild)
--
--    * always use `br` after `good`, `fail`, and `pass`
--
--    * often use `br` after `warn`, unless its really unimportant
--
--    * labels should be roughly hierarchical from general->specific
--
-- Future improvements to consider:
--    * Add timestamps (set via LOG_TIMESTAMPS=1 env var)
--    * Add log level filtering (set via LOG_LEVEL=warn to suppress info)
--    * Add structured JSON output (set via LOG_FORMAT=json for machine parsing)
--    * Add a `debug` level below `info` for verbose debugging
module Omni.Log
  ( Lvl (..),
    good,
    pass,
    info,
    warn,
    fail,
    debug,
    wipe,

    -- * Debugging
    mark,

    -- * Operators
    (~&),
    (~?),

    -- * Wai Middleware
    wai,

    -- * Low-level
    msg,
    fmt,
    br,
  )
where

import Alpha hiding (pass)
import qualified Data.Text as Text
import qualified Network.Wai as Wai
import Rainbow (chunk, fore, green, magenta, red, white, yellow)
import qualified Rainbow
import qualified System.Environment as Env
import qualified System.IO as IO
import System.IO.Unsafe (unsafePerformIO)

data Lvl = Debug | Good | Pass | Info | Warn | Fail | Mark
  deriving (Eq, Ord)

-- | Get the environment. This should probably return 'Omni.App.Area' instead of
-- 'String', but I don't want to depend on everything in 'Omni.App', so some kind
-- of refactor is needed.
area :: IO String
area =
  Env.lookupEnv "AREA"
    /> maybe "Test" identity

-- | Get the minimum log level from LOG_LEVEL env var (default: Info)
-- Set LOG_LEVEL=debug to see debug messages, LOG_LEVEL=warn to suppress info
minLogLevel :: Lvl
minLogLevel =
  unsafePerformIO <| do
    Env.lookupEnv "LOG_LEVEL" /> \case
      Just "debug" -> Debug
      Just "info" -> Info
      Just "warn" -> Warn
      Just "fail" -> Fail
      _ -> Info
{-# NOINLINE minLogLevel #-}

msg :: Lvl -> [Text] -> IO ()
msg lvl labels
  | lvl < minLogLevel = pure () -- Skip messages below minimum level
  | otherwise =
      area +> \case
        "Live" -> putDumb
        _ ->
          Env.lookupEnv "TERM" +> \case
            Just "dumb" -> putDumb
            Nothing -> putDumb
            _ -> Rainbow.hPutChunks IO.stderr [fore color <| clear <> chunk txt <> "\r"]
  where
    -- For systemd-journal, emacs *compilation* buffers, etc.
    putDumb = putStr <| txt <> "\n"
    txt = fmt (label : labels)
    (color, label) = case lvl of
      Debug -> (white, "debg")
      Good -> (green, "good")
      Pass -> (green, "pass")
      Info -> (white, "info")
      Warn -> (yellow, "warn")
      Fail -> (red, "fail")
      Mark -> (magenta, "mark")
    clear = "\ESC[2K"

-- | Helper function for formatting outputs of labels.
fmt :: [Text] -> Text
fmt = Text.intercalate gap

gap :: Text
gap = ":  "

br :: IO ()
br = Rainbow.hPutChunks stderr ["\n"] >> IO.hFlush stderr

wipe :: IO ()
wipe = hPutStr stderr ("\r" :: Text) >> IO.hFlush stderr

good, pass, info, warn, fail, debug :: [Text] -> IO ()
good = msg Good
pass = msg Pass
info = msg Info
warn = msg Warn
fail = msg Fail
debug = msg Debug

-- | Like 'Debug.trace' but follows the patterns in this module
mark :: (Show a) => Text -> a -> a
mark label val =
  unsafePerformIO <| do
    msg Mark [label, tshow val]
    br
    pure val

-- | Pipelined version of 'mark'.
--
-- @
-- mark label val = val ~& label
-- @
(~&) :: (Show a) => a -> Text -> a
val ~& label = mark label val

-- | Conditional mark.
(~?) :: (Show a) => a -> (a -> Bool) -> Text -> a
(~?) val test label = if test val then mark label val else val

wai :: Wai.Middleware
wai app req sendResponse =
  app req <| \res ->
    info
      [ str <| Wai.requestMethod req,
        show <| Wai.remoteHost req,
        str <| Wai.rawPathInfo req
      ]
      >> br
      >> sendResponse res